Literate DocBook XML Stylesheets
Part of
Literate Programming in XML
05 Oct 2001
$Id: ldocbook.xweb,v 1.4 2002/01/06 19:27:56 nwalsh Exp $
0.1
05 Oct 2001
ndw
Initial draft.
NormanWalsh
The ldocbook.xsl stylesheet transforms an
XWEB documentation file (a woven
XWEB document)
into HTML documentation.
This stylesheet assumes that fragments appear inside DocBook
section elements. Some additional customization of
the and
will be required
to support a different organization.
The Stylesheets
This document describes both the HTML and XSL Formatting Objects
versions of the stylesheet.
The HTML Stylesheet
The stylesheet performs some initialization and establishes
templates for the Literate Programming elements that can appear in
the documentation. Most of the documentation elements will be
DocBook elements handled by the imported stylesheet.
<xsl:stylesheet xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:verb="com.nwalsh.saxon.Verbatim"
exclude-result-prefixes="verb src"
version="1.0">
<xsl:import xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:verb="com.nwalsh.saxon.Verbatim"
href="http://docbook.sourceforge.net/release/xsl/current/html/docbook.xsl"/>
</xsl:stylesheet>
The Chunking HTML Stylesheet
The stylesheet performs some initialization and establishes
templates for the Literate Programming elements that can appear in
the documentation. Most of the documentation elements will be
DocBook elements handled by the imported stylesheet.
<xsl:stylesheet xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:verb="com.nwalsh.saxon.Verbatim"
exclude-result-prefixes="verb src"
version="1.0">
<xsl:import xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:verb="com.nwalsh.saxon.Verbatim"
href="http://docbook.sourceforge.net/release/xsl/current/html/chunk.xsl"/>
</xsl:stylesheet>
The FO Stylesheet
The stylesheet performs some initialization and establishes
templates for the Literate Programming elements that can appear in
the documentation. Most of the documentation elements will be
DocBook elements handled by the imported stylesheet.
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:verb="com.nwalsh.saxon.Verbatim"
exclude-result-prefixes="verb src fo"
version="1.0">
<xsl:import xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:verb="com.nwalsh.saxon.Verbatim"
href="http://docbook.sourceforge.net/release/xsl/current/fo/docbook.xsl"/>
<xsl:param xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:verb="com.nwalsh.saxon.Verbatim"
name="page.margin.outer"
select="'1in'"/>
<xsl:param xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:verb="com.nwalsh.saxon.Verbatim"
name="title.margin.left"
select="'-0pt'"/>
</xsl:stylesheet>
Initialization
The stylesheet initializes the processor by loading its version
information (stored in a separate file because it is shared by several
stylesheets), importing the base DocBook stylesheet, setting some
parameters, and setting up
some internationalized text.
<xsl:include href="../VERSION"/>
<xsl:template match="revhistory"
mode="titlepage.mode"/>
Parameters
In DocBook Literate Programming documentation, we always number
sections and verbatim environments.
<xsl:param name="section.autolabel"
select="1"/>
<xsl:param name="linenumbering.everyNth"
select="5"/>
<xsl:param name="linenumbering.separator"
select="'| '"/>
Localization
Localized text in the DocBook stylesheets makes use of an
external document to determine the nature of, among other things,
element titles and cross references.
Cross references to src:fragments are not
supported in the stock stylesheets (since there is no such element
in DocBook).
In order to make cross references work properly, we must provide
an appropriate localization for src:fragment titles.
We do this by pointing the local.l10n.xml
at ourselves (at the stylesheet document).
In our local localization document, we add an
l:i18n element to provide the necessary context.
If you want to support DocBook Literate Programming in other
languages, this section will have to be updated.
<xsl:param name="local.l10n.xml"
select="document('')"/>
<l:i18n>
<l:l10n language="en">
<l:context name="title">
<l:template name="fragment"
text="%t"/>
</l:context>
</l:l10n>
</l:i18n>
Process HTML Fragments
Fragments are output as verbatim environments with numbered lines,
if possible. A table is used to make the listings stand out.
<xsl:template match="src:fragment">
<xsl:param name="suppress-numbers"
select="'0'"/>
<xsl:param name="linenumbering"
select="'numbered'"/>
<xsl:variable name="section"
select="ancestor::section[1]"/>
<xsl:variable name="id"
select="@id"/>
<xsl:variable name="referents"
select="//src:fragment[.//src:fragref[@linkend=$id]]"/>
<div class="src-fragment">
<a name="{@id}"/>
<table border="1"
width="100%">
<tr>
<td>
<p>
<b>
<xsl:apply-templates select="."
mode="label.markup"/>
</b>
<xsl:if test="$referents">
<xsl:text>: </xsl:text>
<xsl:for-each select="$referents">
<xsl:if test="position() > 1">, </xsl:if>
<a>
<xsl:attribute name="href">
<xsl:call-template name="href.target">
<xsl:with-param name="object"
select="."/>
</xsl:call-template>
</xsl:attribute>
<xsl:apply-templates select="."
mode="label.markup"/>
</a>
</xsl:for-each>
</xsl:if>
</p>
</td>
</tr>
<tr>
<td>
<xsl:choose>
<xsl:when test="$suppress-numbers = '0' and $linenumbering = 'numbered' and $use.extensions != '0' and $linenumbering.extension != '0'">
<xsl:variable name="rtf">
<xsl:apply-templates/>
</xsl:variable>
<pre class="{name(.)}">
<xsl:copy-of select="verb:numberLines($rtf)"/>
</pre>
</xsl:when>
<xsl:otherwise>
<pre class="{name(.)}">
<xsl:apply-templates/>
</pre>
</xsl:otherwise>
</xsl:choose>
</td>
</tr>
</table>
</div>
</xsl:template>
Fragment labels and titles must also be supported.
Fragment Labels
A fragment label consists of a section mark followed by the
label of the current section and the number of the fragment within
that section.
<xsl:template match="src:fragment"
mode="label.markup">
<xsl:variable name="section"
select="ancestor::section[1]"/>
<xsl:text>ยง</xsl:text>
<xsl:choose>
<xsl:when test="$section">
<xsl:variable name="section.label">
<xsl:apply-templates select="$section"
mode="label.markup"/>
</xsl:variable>
<xsl:choose>
<xsl:when test="string($section.label) = ''">
<xsl:number from="section"/>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="$section.label"/>
<xsl:text>.</xsl:text>
<xsl:number from="section"/>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:number from="/"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
Fragment Titles
A fragment title is the title of the section that contains it.
<xsl:template match="src:fragment"
mode="title.markup">
<xsl:variable name="section"
select="ancestor::section[1]"/>
<xsl:if test="$section">
<xsl:apply-templates select="$section"
mode="title.markup"/>
</xsl:if>
</xsl:template>
Process FO Fragments
Fragments are output as verbatim environments with numbered lines,
if possible.
<xsl:template match="src:fragment">
<xsl:param name="suppress-numbers"
select="'0'"/>
<xsl:param name="linenumbering"
select="'numbered'"/>
<xsl:variable name="section"
select="ancestor::section[1]"/>
<xsl:variable name="id"
select="@id"/>
<xsl:variable name="referents"
select="//src:fragment[.//src:fragref[@linkend=$id]]"/>
<fo:block xsl:use-attribute-sets="formal.object.properties"
keep-together="always"
border-style="solid"
border-width="0pt"
border-before-width="0.25pt"
border-after-width="0.25pt">
<fo:block id="{@id}"
border-width="0pt"
border-style="solid"
border-after-width="0.25pt">
<fo:inline font-weight="bold">
<xsl:apply-templates select="."
mode="label.markup"/>
</fo:inline>
<fo:inline>
<xsl:if test="$referents">
<xsl:text>: </xsl:text>
<xsl:for-each select="$referents">
<xsl:if test="position() > 1">, </xsl:if>
<xsl:apply-templates select="."
mode="label.markup"/>
</xsl:for-each>
</xsl:if>
</fo:inline>
</fo:block>
<fo:block wrap-option="no-wrap"
text-align="start"
white-space-collapse="false"
linefeed-treatment="preserve"
xsl:use-attribute-sets="monospace.verbatim.properties">
<xsl:variable name="rtf">
<xsl:apply-templates/>
</xsl:variable>
<xsl:choose>
<xsl:when test="$suppress-numbers = '0' and $linenumbering = 'numbered' and $use.extensions != '0' and $linenumbering.extension != '0'">
<xsl:call-template name="number.rtf.lines">
<xsl:with-param name="rtf"
select="$rtf"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="$rtf"/>
</xsl:otherwise>
</xsl:choose>
</fo:block>
</fo:block>
</xsl:template>
Process HTML Fragment References
A fragment reference has exactly the same semantics as a DocBook
xref.
<xsl:template match="src:fragref">
<xsl:call-template name="xref"/>
</xsl:template>
Fragment Cross-Reference Text
Cross references to fragments produce the fragment label
and title.
<xsl:template match="src:fragment"
mode="xref-to">
<xsl:variable name="section"
select="ancestor::section[1]"/>
<i>
<xsl:apply-templates select="."
mode="label.markup"/>
<xsl:text>. </xsl:text>
<xsl:apply-templates select="."
mode="title.markup"/>
</i>
</xsl:template>
Process FO Fragment References
A fragment reference has exactly the same semantics as a DocBook
xref.
<xsl:template match="src:fragref">
<xsl:call-template name="xref"/>
</xsl:template>
Fragment Cross-Reference Text
Cross references to fragments produce the fragment label
and title.
<xsl:template match="src:fragment"
mode="xref-to">
<xsl:variable name="section"
select="ancestor::section[1]"/>
<fo:inline font-style="italic">
<xsl:apply-templates select="."
mode="label.markup"/>
<xsl:text>. </xsl:text>
<xsl:apply-templates select="."
mode="title.markup"/>
</fo:inline>
</xsl:template>